/*
The Botburger is a pickup spawned by the BRUT mod that gets the bots to move
towards the center of the zone. The mod spawns it when a bot moves outside the
safe area and places it between the bot and the zone center in an effort to 
lure it back into the play area. The pickup has no other usage and is destroyed 
if it is touched by any players. MaxDesireability is very high so that any other
pickups are ignored and the bot moves towards the desired direction.
*/
class BotBurger expands PickUp;

//Destroy on touch
auto state Pickup
{
   function Touch(actor Other)
   {
      local Inventory Copy;

      if (ValidTouch(Other))
			Destroy();
   }

   function BeginState()
   {
      Super.BeginState();
      NumCopies = 0;
   }
}

//Make it as attractive as possible in all situations
event float BotDesireability(pawn Bot)
{
   local float desire;

   desire = MaxDesireability;
   return desire;
}

//No respawn
function SetRespawn()
{
   Destroy();
}

state Activated
{
}

state DeActivated
{
}

defaultproperties
{
	bOnlyOwnerSee=True
 	bHidden=True
	bCanHaveMultipleCopies=False
	bAutoActivate=False
	bActivatable=False
	bDisplayableInv=False
	PickupMessage=""
	RespawnTime=999
	PickupViewMesh=LodMesh'UnrealI.InvisibilityMesh'
	MaxDesireability=50.00000
	Icon=Texture'UnrealI.Icons.I_Invisibility'
	Mesh=LodMesh'UnrealI.InvisibilityMesh'
	AmbientGlow=0
	CollisionRadius=15.000000
	CollisionHeight=17.000000
}
